Windows install ISO FOG server 1.3

[Quazz]

@raice Don’t use x: to mount a network drive as WinPE will mount itself on X: on boot already!

[aruhuno]

I’m using that with FOG 1.2.0:

:WS2012R2
sanboot --no-describe --drive 0x81 ${boot_url}discimg/WS2012R2.iso
goto MENU

[Wayne Workman]

@raice said:

The next step is to automate the installations.

I’d rather my installations not be automated lol. I WANT to do it manually, then I’ll take an image with FOG and blast it out to 500 computers in an automated fashion…

[george1421]

@Wayne-Workman said:

I’d rather my installations not be automated lol. I WANT to do it manually, then I’ll take an image with FOG and blast it out to 500 computers in an automated fashion…

Really? And out of those 500 systems, how many are the same make and model? Lets make it a bit harder for our selves like, lets install the french version of MS Windows and then load a US English mui so the Americans can use the computer.

While I understand what the OP is trying to accomplish there are better/easier ways than using FOG to hand out the iso images (thinking a multiboot flash drive would be less complex).

[Wayne Workman]

@george1421 I make an image per model. and our 1Gbps network is far faster than USB 2.0 or optical disk. Plus, it’s handy. I will be able to load an alternative OS anywhere at any moment instead of carrying around flash drives.

[raice]

@Wayne-Workman in out environment that’s nearly impossible. We sell new and second hand laptops. So we got different models every day. Now we can just start the installation and sysprep it afterwards.

Do you want the documentation or did you write your own now? I almost finished and only need to translate it.

[Quazz]

@echo off

rem The fileserver IP
set FILESERVER=192.168.1.155

rem Share on the fileserver.
set SHARE=INSTALLERS\ISOFILES\0-WINPE

rem Username for the share
set SHAREUSER=root

rem Password for the share
set SHAREPASS=root

rem amd64 or x86
set ARCH=amd64

rem Path to hold working files. Needs about 500MB of free space.
set PEPATH="c:\winpe_%ARCH%"

rem ##########################################################
rem     Don't edit anything below here
rem ##########################################################
 
echo Creating the PE image
call copype.cmd %ARCH% %PEPATH% > NUL
 
echo Mounting the image
dism /Mount-Wim /WimFile:%PEPATH%\media\sources\boot.wim /index:1 /MountDir:%PEPATH%\mount /quiet
 
echo Adding commands to the startup script in PE
echo. >> %PEPATH%\mount\windows\system32\startnet.cmd
echo ping %FILESERVER% >> %PEPATH%\mount\windows\system32\startnet.cmd
echo net use z: \\%FILESERVER%\%SHARE% %SHAREPASS% /u:%FILESERVER%\%SHAREUSER% >> %PEPATH%\mount\windows\system32\startnet.cmd
echo z: >> %PEPATH%\mount\windows\system32\startnet.cmd
echo z:\64.bat >> %PEPATH%\mount\windows\system32\startnet.cmd
 
echo Creating the pxeboot directory
mkdir %PEPATH%\pxeboot > NUL
mkdir %PEPATH%\pxeboot\Fonts > NUL
copy /y %PEPATH%\mount\windows\boot\Fonts\*.* %PEPATH%\pxeboot\Fonts\ > NUL
copy /y "%WinPERoot%\%ARCH%\Media\Boot\boot.sdi" %PEPATH%\pxeboot\ > NUL
copy /y "%WinPERoot%\%ARCH%\Media\Boot\BCD" %PEPATH%\pxeboot\ > NUL
 
echo Unmounting the image
dism /unmount-Wim /MountDir:%PEPATH%\mount /Commit /quiet
 
echo Optimizing the image
imagex /EXPORT %PEPATH%\media\sources\boot.wim 1 %PEPATH%\pxeboot\boot.wim > NUL
 
 
echo.
echo All the files you need for your PXE server are in: %PEPATH%\pxeboot\

This script needs to be called from the Deployment and Images Tool Environment command prompt.

I based myself on http://www.wcooke.org/wiki/Installing_Windows_using_PXELINUX but modified it since certain things didn’t work (it would create a corrupt BCD when there’s a perfectly fine working one included with WinPE) and other things were unnecessary.

If you make changes to the script and call it again make sure to delete the target directory first or your startnet.cmd will get messed up!

edit: Added ping command to give network drivers time to load before attempting to mount the network location.

[Wayne Workman]

@raice Your instructions would be greatly appreciated, the more the better! We can compare notes and come up with the best solution!

And for your environment, yes, being able to install windows from the network on many different models of PCs is the best option for you! I imagine you are a fan of Fog’s “Quick Image” feature that doesn’t require a registered computer, eh?